Refactor/maven (#889)

* mavenize * mavenization * mavenization * mavenization * mavenization * mavenization * mavenization * mavenization * mavenization * fix * app framework update * fix lib * lib * fix mavenized * fix mavenized * fix mavenized * fix mavenized * fix mavenized * fix mavenized * fix mavenized * fix mavenized * building for win and linux * Create run.bat * fixes for netlist * cleanup * unit tests * unit tests * configurable high dpi * performance upgrade * performance upgrade * rotate bug * Omit boards, wires, traces, terminals, etc from Spice netlist output * splash version update * optimize libs * optimize libs * updates * mac build maven * ruler optimization, moved images * cleanup * notarization * test workflow * build * Update pom.xml * Update pom.xml * Create README.md * Create test.yml * maven * build
2026-11-10 17:22:09 +10:00 · 2025-03-20 19:44:40 +01:00
parent ccb98d1953
commit 4093641b7e
1232 changed files with 17811 additions and 14965 deletions
@@ -0,0 +1,62 @@
+[Setup]
+AppName=DIY Layout Creator
+AppVersion={#diylcver}
+DefaultDirName={pf}\DIYLC
+DefaultGroupName=DIY Layout Creator
+UninstallDisplayIcon={app}\diylc.exe
+Compression=zip
+SolidCompression=yes
+OutputDir=..\..\target
+OutputBaseFilename=diylc-{#diylcver}-win64
+ChangesAssociations=yes
+AlwaysShowDirOnReadyPage=yes
+; Only allow the installer to run on x64-compatible systems,
+; and enable 64-bit install mode.
+ArchitecturesAllowed={#arch}
+ArchitecturesInstallIn64BitMode={#arch}
+
+[Files]
+Source: "diylc-{#arch}.exe"; DestDir: "{app}"; DestName: "diylc.exe"
+Source: "..\..\src\main\resources\icons\diylc_file.ico"; DestDir: "{app}"
+Source: "..\..\target\diylc.jar"; DestDir: "{app}"
+Source: "..\..\target\jre_win\*"; DestDir: "{app}\jre17"; Flags: ignoreversion recursesubdirs
+Source: "donate.bmp"; DestDir: "{tmp}"; Flags: dontcopy nocompression
+
+[Registry]
+Root: HKCR; Subkey: ".diy"; ValueData: "DIYLC"; Flags: uninsdeletevalue; ValueType: string; ValueName: ""
+Root: HKCR; Subkey: "DIYLC"; ValueData: "Program DIYLC";  Flags: uninsdeletekey; ValueType: string; ValueName: ""
+Root: HKCR; Subkey: "DIYLC\DefaultIcon"; ValueData: "{app}\diylc_file.ico"; ValueType: string;  ValueName: ""
+Root: HKCR; Subkey: "DIYLC\shell\open\command";  ValueData: """{app}\diylc.exe"" ""%1"""; ValueType: string; ValueName: ""
+
+[Icons]
+Name: "{group}\DIY Layout Creator"; Filename: "{app}/diylc.exe"
+
+[Run]
+Filename: "{app}/diylc.exe"; Description: "Launch DIYLC on exit"; Flags: postinstall skipifsilent
+
+[Code]
+  
+procedure LicenseLinkClick(Sender: TObject);
+var
+  ErrorCode: Integer;
+begin
+  ShellExec('', 'http://www.diy-fever.com/donate', '', '', SW_SHOW, ewNoWait, 
+    ErrorCode);
+end;
+
+procedure InitializeWizard;
+var donateImage: TBitmapImage;
+begin
+  ExtractTemporaryFile('donate.bmp');
+  
+  donateImage := TBitmapImage.Create(WizardForm);
+  donateImage.Parent:= WizardForm;
+  donateImage.Bitmap.LoadFromFile(ExpandConstant('{tmp}\donate.bmp'));
+  donateImage.Stretch := True;
+  donateImage.Width := 142;
+  donateImage.Height := 27;
+  donateImage.Left := 8;
+  donateImage.Top := WizardForm.InnerPage.Height + 10;
+  donateImage.Cursor := crHand;
+  donateImage.OnClick := @LicenseLinkClick;  
+end;